/*------------------
  File Name: install.dat

  History: Cheok K. Lai (June 22, 1992) File created
	   Robert Gilsdorf (August 27, 1992) File ammended
  Description: This is a script file that automates the installation process 
	       of the Fahrenheit VA display drivers.
-------------------*/
@DefineProject
	@Name      = "Fahrenheit"
	@Version   = "4.8"
	@Immediate = 1 
	@Subdir    = "\\"
	@OutDrive  = C
@EndProject

/*----------------------------- Define String -----------------------------*/
@DefineVars
 @Qstring @msgDDI       = "Display Driver Installation"
 @Qstring @msgDrive     = "Please Select Destination Drive:"
 @Qstring @msgDir       = "Please Enter a Directory name or select ENTER to accept default."
 @Qstring @msgPSAV      = "Please Select Version:"
 @Qstring @msgPSAA      = "Please Select An Application:"
 @Qstring @msgDDNE      = "does not exist."
 @Qstring @msgCont      = "If you choose to continue, one will be created."
/*  @Qstring @msgNoFile    = "Your input directory may be missing some files:" */
 @Qstring @msgNoFile    = "Some files are missing in your input directory:"
 @Qstring @msgNPI       = "may not be properly installed."
 @Qstring @Reenter      = " Enter Again"
 @Qstring @Cont         = "  Continue  "
 @Qstring @NameWin      = "Microsoft Windows"
 @Qstring @NameCADsys   = "Computer Aided Design"
 @Qstring @NameACAD     = "AutoCAD"
 @Qstring @NameCADKey   = "CADKey"
 @Qstring @NameCADvance = "CADVance"
 @Qstring @NameDataCAD  = "DataCAD"
 @Qstring @NameGenCADD  = "Generic CADD"
 @Qstring @NameMicroCAD = "MicroStation"
 @Qstring @NameVersaCAD = "VersaCAD"
 @Qstring @NameDesk     = "Desktop Publishing"
 @Qstring @NameGem      = "GEM Desktop"
 @Qstring @NameVentura  = "Ventura Publisher"
 @Qstring @NameLotus    = "Lotus 1-2-3"
 @Qstring @NameWord     = "Word Processing"
 @Qstring @NameWP       = "WordPerfect"
 @Qstring @NameMSWord   = "Microsoft Word"
 @Qstring @NameUtil     = "Orchid Utilities"
 @Qstring @NameMore     = "More...."
 @Qstring @NameOS2       = "IBM OS/2"
 @Qstring @NameSCO       = "SCO Unix"
 @Qstring @NameIntractv  = "Interactive Unix"
 @Qstring @NameOtherp    = "Other Orchid Products"
 @Qstring @NameTchsupt   = "Technical Support"
 @Qstring @NameSample    = "Build Voice Notes Playback Diskette" 
 @EndVars

/*--------------------- Introduction Message -----------------------------*/
@Display
@If (@CheckCard ("c000", "00F6", "Fahrenheit VA") == 1)
  @Goto MenuJumper
@Elseif (@CheckCard ("c000", "011c", "Fahrenheit 1280") == 1)
  @Goto MenuJumper
@Elseif (@CheckCard ("c000", "00F6", "Fahrenheit 1280 Plus") == 1)
  @Goto MenuJumper
@Else
 @Cls

		ллллллллллллллллл ERROR лллллллллллллллл
		л                                      л
		л  An Orchid Fahrenheit video adapter  л
		л  is not detected in your system.     л
		л                                      л
		л  If you choose to continue this      л
		л  installation, the driver will not   л
		л  respond correctly.                  л
		л                                      л
		л  PRESS F3 TO ABORT INSTALLATION      л
		л                                      л
		л                                      л
		л                                      л
		лллллллллллллллллллллллллллллллллллллллл
 
 @Pause
@Endif


    

MenuJumper:
@cls
@If (@CheckCard ("C000", "00F6", "Fahrenheit VA") == 1)





		   Orchid Fahrenheit VA Series Video Adapter


		      Display Driver Installation Program


			       Disk Release 4.8




  @Pause
@Elseif (@CheckCard ("C000", "011C", "Fahrenheit 1280") == 1)
 





		      Orchid Fahrenheit 1280 Video Adapter


		      Display Driver Installation Program


			       Disk Release 4.8





  @Pause

@Elseif (@CheckCard ("C000", "00F6", "Fahrenheit 1280 Plus") == 1)
 





		   Orchid Fahrenheit 1280 Plus Video Adapter


		      Display Driver Installation Program


			       Disk Release 4.8




  @Pause


@Cls
@Endif

@If (@Chk2e8)

		лллллллллллллллл Warning ллллллллллллллл
		л                                      л
		л  Fax Modem OR Serial Port OR Scanner л
		л  Adapter is utlizing the I/O port of л
		л  Fahrenheit Video Adapter.           л
		л                                      л
		л  Please reconfigure your Fax Modem   л
		л  OR Serial Port OR Scanner at other  л
		л  I/O port address, i.e. Avoid I/O    л
		л  port address 2e8.                   л
		л                                      л
		л                                      л
		л  You may continue the Installation,  л
		л  and reconfigure your I/O port       л
		л  address after Installation is       л
		л  completed.                          л
		л                                      л
		лллллллллллллллллллллллллллллллллллллллл
@Pause
@Endif

@EndDisplay



/*--------------------- Drive C: check for Installation-----------------*/

@If ("@Indrive"=="C")
    @Display

    The Install Program must be run from a Floppy Drive.  Please use the  
    <ESC> key and start over from the Floppy drive.

     @Pause
    @Abort
   @EndDisplay
@EndIf

/*---------------------- Installation Main Menu --------------------------*/
MenuMain:
 @FlushOptions
 @EnableF1(1)
 @GetOption
 @Cls
  @Option 1000 = "@NameWin"
  @Option 4000 = "@NameLotus"
  @Option 2000 = "@NameCADsys"
  @If (@CheckCard ("c000", "011c", "Fahrenheit 1280") == 1)
   @Option 3000 = "@NameDesk"  
  @Endif
  @Option 5000 = "@NameWord"
  @Option 5500 = "@NameSample"
  @Option 6000 = "@NameUtil"
  @Option 7000 = "@NameMore"
 
 @EndOption

 @If (@Esc)
     @Exit
 @Elseif (@KeyF1)
     @Goto MenuMainHelp
 @ElseIf (1000 [= @Option)
     @Goto MenuWin
 @ElseIf (2000 [= @Option)
     @Goto MenuCADsys
 @ElseIf (3000 [= @Option)
     @Goto MenuDesktop
 @ElseIf (4000 [= @Option)
     @Goto MenuLotus
 @ElseIf (5000 [= @Option)
     @Goto MenuWordProcess
 @ElseIf (5500 [= @Option)
     @Goto MenuSample
 @ElseIf (6000 [= @Option)
     @Goto MenuUtility
 @ElseIf (7000 [= @Option)
     @Goto MenuInfo
 @Else
     @Goto MenuMain
 @Endif

/*--------------------- Handle Information Menu  ----------------------------*/
MenuInfo:
@ClearOption(7010)
@ClearOption(7020)
@ClearOption(7030)
@ClearOption(7040)
@ClearOption(7045) 
@ClearOption(7050)
 @EnableF1(0)
 @GetOption
 @Cls
	












  @Option 7010 = "@NameOS2"
  @Option 7020 = "@NameSCO"
  @Option 7030 = "@NameIntractv"
  @Option 7040 = "@NameOtherp"
  @Option 7045 = "Other Orchid Video Products"
  @Option 7050 = "@NameTchsupt"


  @EndOption


 @If (@Esc)
     @Goto MenuMain
@ElseIf (7010 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpOS2", "EndOS2")
@ElseIf (7020 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpSCO", "EndSCO")
@ElseIf (7030 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpIntractv", "EndIntractv")
@ElseIf (7040 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpOtherp", "EndOtherp")
@ElseIf (7045 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpFah", "EndFah")
@ElseIf (7050 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpTchsupt", "EndTchsupt")

@endif
@Goto MenuInfo

/*--------------------- Handle Help  Menu  ----------------------------*/


MenuMainHelp:

@If (1000 [= @Option)  /* Windows */
  @Help ("@ExePath\\install.hlp", "HelpWin", "EndWin")
@ElseIf (4000 [= @Option)  /* Lotus */
  @Help ("@ExePath\\install.hlp", "HelpLotus", "HelpLotusInst")
@Elseif (2000 [= @Option) /* CAD's */
  @Help ("@ExePath\\install.hlp", "HelpCADMain", "EndCADMain")
@Elseif (3000 [= @Option) /* Desktop */
  @Help ("@ExePath\\install.hlp", "HelpDeskMain", "EndDeskMain")
@Elseif (5000 [= @Option) /* Word Process */
  @Help ("@ExePath\\install.hlp", "HelpWordPMain", "EndWordPMain")
@Elseif (5500 [= @Option) /* Word Process */
  @Help ("@ExePath\\install.hlp", "HelpCopy", "EndCopy")
@Elseif (6000 [= @Option) /* Utility */
  @Help ("@ExePath\\install.hlp", "HelpUtilMain", "EndUtilMain")
@Elseif (7000 [= @Option) /* More.... */
  @Help ("@ExePath\\install.hlp", "HelpMore", "EndMore")
@EndIf   

@Goto MenuMain

/*--------------- Windows 3.x Driver Installation (1000) -----------------*/
MenuWin:

@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B 
 @Cls
 @NameWin @msgDDI
 @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuMain @EndIf

@GetSubdir
 @Default = "\\WINDOWS"    
 @Cls
 @NameWin @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuWin @EndIf

@ClearOption(1)
@ClearOption(2)
@EnableF1(0)
@GetOption
 @LocalWindow (10,39) 
 @If (@Exists "@OutDrive:\\@SubDir" == 0)
  @Cls
  @NameWin @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
 @ElseIf ((@Exists "@OutDrive:\\@SubDir\\winver.exe" == 0) ||
	  (@Exists "@OutDrive:\\@SubDir\\win.ini" == 0))
  @Cls
  @NameWin @msgDDI
  @msgNoFile
  @OutDrive:@SubDir
  @NameWin @msgNPI
 @Else
  @Goto CopyFileWin
 @EndIf
 @Option 1 = "@Reenter"
 @Option 2 = "@Cont"
@EndOption
@If ((@Esc) || (1 [= @Option))
  @Goto MenuWin
@Endif


CopyFileWin:
@DefineDisk
@Label = "Disk #1"
@BeginLib FAHDRVVA.001 

 @F orchidf.cpl  @O @OutDrive:\@SubDir\SYSTEM\*.*
 @F orchidf.hlp  @O @OutDrive:\@SubDir\SYSTEM\*.* 
 @F orchidf.2gr  @O @OutDrive:\@SubDir\SYSTEM\*.*  
 @F orchidf.drv  @O @OutDrive:\@SubDir\SYSTEM\*.*
 @F orchidv.drv  @O @OutDrive:\@SubDir\SYSTEM\*.*
 @F orchid1.drv  @O @OutDrive:\@SubDir\SYSTEM\*.*
 @F orckey.dll   @O @OutDrive:\@SubDir\SYSTEM\*.*  
 @F magnify.exe  @O @OutDrive:\@SubDir\SYSTEM\*.*  
 @F vmp_mm.dll   @O @OutDrive:\@SubDir\SYSTEM\*.* 
 @F vctl.dll     @O @OutDrive:\@SubDir\SYSTEM\*.*
 @F orchhook.dll @O @OutDrive:\@SubDir\SYSTEM\*.*
 

 @If (@CheckCard ("C000", "00F6", "Fahrenheit VA") == 1)
  @F orchnote.exe @O @OutDrive:\orchid\*.* 
 @EndIf


 @If (@CheckCard ("c000", "011c", "Fahrenheit 1280") == 1)
    @F orch911.drv  @O @OutDrive:\@SubDir\SYSTEM\orchid1.drv
 @Else
    @F orch801.drv  @O @OutDrive:\@SubDir\SYSTEM\orchid1.drv
 @Endif


 @If (@CheckFile ("@OutDrive:\\@SubDir\\winver.exe", "207", "Windows Version 3.00"))
  @F orchid.exe  @O @OutDrive:\@SubDir\*.*
  @F orchd30.inf @O @OutDrive:\@SubDir\SYSTEM\orchidf.inf
  @F orchd30.386 @O @OutDrive:\@SubDir\SYSTEM\*.* 
  @F orchd30.3gr @O @OutDrive:\@SubDir\SYSTEM\*.* 
  @F fva.exe     @O @OutDrive:\@SubDir\SYSTEM\*.*
 @Else
  @F orchidf.inf @O @OutDrive:\@SubDir\SYSTEM\*.* 
  @F orchidf.386 @O @OutDrive:\@SubDir\SYSTEM\*.* 
  @F orchidf.3gr @O @OutDrive:\@SubDir\SYSTEM\*.*
  @F fva.exe     @O @OutDrive:\@SubDir\SYSTEM\*.*
 @Endif




@EndLib 
@EndDisk





@Display

 @Cls
 @System "@OutDrive:\\@SubDir\\SYSTEM\\fva.exe"
 @Delete ("@OutDrive:\\@SubDir\\SYSTEM\\fva.exe")
 @Cls

@EndDisplay
		      


 @If (@CheckCard ("0000", "04e8", "") == 0)
   @Goto MenuModify
 @Elseif (@CheckFile ("@OutDrive:\\@SubDir\\winver.exe", "207", "Windows Version 3.00"))
   @Goto MenuModify
 @Else
MenuVOICE:
    @ClearOption(60) 
    @ClearOption(61)  
    @ClearOption(62)
    @EnableF1(1)

    @GetOption
     @LocalWindow (10,40)
     @Cls
     Would you like Voice Notes....
     (Hit the <F1> Key for more information.)
     @Option 60 = "Loaded and INSTALLED in Windows"
     @Option 61 = "Loaded, but NOT ACTIVATED in Windows"
     @Option 62 = "NOT LOADED AT ALL!"
    @EndOption

    @If (@Esc)
      @Goto MenuVOICE
    @Elseif (@KeyF1)
      @Help ("@ExePath\\install.hlp","HelpVOICE","EndVOICE")
    @Elseif (60 [= @Option)
      @Goto MenuVOICENOTE
    @Elseif (61 [= @Option)
      @Goto MenuVOICENOTE
    @Elseif (62 [= @Option)
      @Goto MenuModify
 @Endif
   @Goto MenuVOICE 
 @Endif   

MenuVOICENOTE:
   @DefineDisk
    @Label = "Disk #1"
    @BeginLib FAHDRVVA.001 
   
    @F orchnote.exe @O @OutDrive:\orchid\*.* 
    @F vmp_mm.dll   @O @OutDrive:\orchid\*.* 
    @F vctl.dll     @O @OutDrive:\orchid\*.* 
    @F orchhook.dll @O @OutDrive:\orchid\*.* 
    @F ovn.hlp      @O @OutDrive:\orchid\*.*
    @F orckey.dll   @O @OutDrive:\orchid\*.*  
    @F orcsnd.drv   @O @OutDrive:\@SubDir\SYSTEM\*.*
    @F sndsetup.cpl @O @OutDrive:\@SubDir\SYSTEM\*.*
    @F sndsetup.hlp @O @OutDrive:\@SubDir\SYSTEM\*.*
    @F orchinst.exe @O @OutDrive:\@SubDir\*.*
    @F orchinst.dat @O @OutDrive:\@SubDir\*.*
    @F orcdde.dll   @O @OutDrive:\@SubDir\*.*
    
    @EndLib 
   @EndDisk


MenuModify: 
@Display
 @If (@CheckFile ("@OutDrive:\\@SubDir\\winver.exe", "207", "Windows Version 3.00"))
  Modifying WIN.INI of Windows 3.0.
  @DeleteStr ("@OutDrive:\\@SubDir\\win.ini", "windows", "run", "orchid.exe")
  @WriteFile ("@OutDrive:\\@SubDir\\win.ini", "windows", "load=", "orchid.exe", "APPEND")
 @Elseif (@Exists "@OutDrive:\\@SubDir\\orchid.ini" == 0)
  Modifying WIN.INI of Windows 3.1
  @WriteFile ("@OutDrive:\\@SubDir\\win.ini", "windows", "run=", "control.exe", "APPEND")
 @Elseif (@Exists "@OutDrive:\\@SubDir\\progman.orc" == 0)
  @CatFiles ("@OutDrive:\\@SubDir\\progman.ini", "@OutDrive:\\@SubDir\\progman.orc")
 @Endif
 
 @If (60 [= @Option)
  @WriteFile ("@OutDrive:\\@SubDir\\orchinst.dat", "StartUp", "ItemCmd1=", "ItemCmd1=@OutDrive:\\orchid\\orchnote.exe", "REPLACE")
  @WriteFile ("@OutDrive:\\@SubDir\\win.ini", "windows", "load=", "orchinst.exe", "APPEND")
  @WriteFile ("@OutDrive:\\@SubDir\\system.ini", "drivers", "Wave=", "WAVE=ORCSND.DRV", "REPLACE")
 @Endif
 
 @If (61 [= @Option)
  @WriteFile ("@OutDrive:\\@SubDir\\orchinst.dat", "Group", "Group1=", "Group1=Voice Note", "REPLACE")
  @WriteFile ("@OutDrive:\\@SubDir\\orchinst.dat", "Voice Note", "ItemCmd1=", "ItemCmd1=@OutDrive:\\orchid\\orchnote.exe", "REPLACE")
  @WriteFile ("@OutDrive:\\@SubDir\\win.ini", "windows", "load=", "orchinst.exe", "APPEND")
 @Endif

 @If (@CheckCard ("0000", "04e8", "") == 1)
  @WriteFile ("@OutDrive:\\@SubDir\\system\\setup.inf","Installable.Drivers","FahrenheitVA", "FahrenheitVA = x:orcsnd.drv, \"wave\", \" Orchid Fahrenheit VA\", ,, ", "REPLACE") 
 @EndIf

 @If (@CheckCard ("c000", "00F6", "Fahrenheit VA") == 1)
   @Delete ("@OutDrive:\\@SubDir\\SYSTEM\\orchidf.drv")
   @Cls
 @Endif
 
 @If (@CheckCard ("C000", "00F6", "Fahrenheit 1280 Plus") == 1)
   @Delete ("@OutDrive:\\@SubDir\\SYSTEM\\orchidf.drv")
   @Cls
 @Endif

 @If (@CheckCard ("c000", "011c", "Fahrenheit 1280") == 1)
   @Delete ("@OutDrive:\\@SubDir\\SYSTEM\\orchidv.drv")
   @Cls
 @Endif

@EndDisplay
@Help ("@ExePath\\install.hlp", "HelpWin", "EndWin")
@Display
@Cls




***************************************************************************
*** The installation of the Orchid Window HyperDriver is now completed. ***
***************************************************************************


@Pause
@EndDisplay
@Goto MenuMain

/*--------------- Lotus 1-2-3 Driver Installation (4000) -----------------*/
MenuLotus:



@Help ("@ExePath\\install.hlp", "HelpLotusInst", "EndLotus")
@Goto MenuMain

/*----------------- Utility Installation (6000) --------------------------*/
MenuUtility:

@ClearOption(6100) /* fscan */
@ClearOption(6200) /* fmode */
@ClearOption(6300) /* fdemo */
@ClearOption(6400) /* all of the above */
@EnableF1(1)

@GetOption
 @Cls
 @NameUtil Installation:
 @msgPSAA
 @Option 6100 = " FSCAN.COM"
 @Option 6200 = " FMODE.EXE"
 @Option 6300 = " FDEMO.EXE"
 @Option 6400 = "All of Above"
@EndOption

@If (@Esc)
 @Goto MenuMain
@Elseif (@KeyF1)
 @Help ("@ExePath\\install.hlp","HelpUtilMain","EndUtilMain")
 @Goto MenuUtility
@Endif

InputDirUtil:
@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
 @Cls
 @NameUtil Installation:
 @msgDrive














/* The @NameUtil may be placed in any directory on your computer
 (e.g., C:\\FAH_UTIL).*/
@EndOutDrive
@If (@Esc) @Goto MenuUtility @Endif

@GetSubdir
 @Default = "\\FAH_UTIL"
 @Cls
 @NameUtil Installation
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuUtility @Endif

@ClearOption(1)
@ClearOption(2)
@If ((@Exists "@OutDrive:\\@SubDir") == 0)
 @EnableF1(0)
 @GetOption
  @LocalWindow (10,39) 
  @Cls
  @NameUtil Installation
  @OutDrive:@SubDir @msgDDNE
  @msgCont
  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
 @EndOption
@Endif

@If (@Esc)
 @Goto MenuUtility
@ElseIf (1 [= @Option)
  @Goto InputDirUtil
@Endif

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 
 @F fscan.com @O @OutDrive:\@SubDir\*.* @Option 6100 
 @F fmode.exe @O @OutDrive:\@SubDir\*.* @Option 6200 
 @F fdemo.exe @O @OutDrive:\@SubDir\*.* @Option 6300 
 
 @F fscan.com @O @OutDrive:\@SubDir\*.* @Option 6400 
 @F fmode.exe @O @OutDrive:\@SubDir\*.* @Option 6400 
 @F fdemo.exe @O @OutDrive:\@SubDir\*.* @Option 6400 
 
 @EndLib
@EndDisk

@Help ("@ExePath\\install.hlp","HelpUtilFin","EndUtilFin")
@Goto MenuUtility

/*----------------------- CAD system Menu (2000) -------------------------*/
MenuCADsys:
@ClearOption(2100) /*AutoCAD*/
@ClearOption(2200) /*CADKey*/
@ClearOption(2300) /*DataCAD*/
@ClearOption(2400) /*CADVance*/
@ClearOption(2500) /*GenericCADD*/
@ClearOption(2600) /*MicroStation*/
@ClearOption(2700) /*VersaCAD*/
@EnableF1(1)

@GetOption
 @LocalWindow (10,40)
 @Cls
 @NameCADsys @msgDDI
 @msgPSAA
 @Option 2100 = "@NameACAD"
 @Option 2200 = "@NameCADKey"
 @Option 2300 = "@NameDataCAD"
 @Option 2400 = "@NameCADVance"
 @Option 2500 = "@NameGenCADD"
 @Option 2600 = "@NameMicroCAD"
 @Option 2700 = "@NameVersaCAD"
@EndOption

@If (@Esc)
 @Goto MenuMain
@Elseif (@KeyF1)
 @Goto MenuCADsysHelp
@ElseIf (2100 [= @Option)
 @Goto MenuACAD
@ElseIf (2200 [= @Option)
 @Goto MenuCADKey
@ElseIf (2300 [= @Option)
 @Goto MenuDataCAD
@ElseIf (2400 [= @Option)
 @Goto MenuCADVance
@ElseIf (2500 [= @Option)
 @Goto MenuGenCADD
@ElseIf (2600 [= @Option)
 @Goto MenuMicroCAD
@ElseIf (2700 [= @Option)
 @Goto MenuVersaCAD
@Endif

/*------------------ Handle CAD system Help Menu -------------------------*/
MenuCADsysHelp:

@If (2100 [= @Option)
 @Goto MenuACAD
@Elseif (2200 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpCADKey", "EndCADKey")
@Elseif (2300 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpDataCAD", "EndDataCAD")
@Elseif (2400 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpCADVance", "EndCADVance")
@Elseif (2500 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpGenCADD", "EndGenCADD")
@Elseif (2600 [= @Option)
 @Goto MenuMicroCAD
@Elseif (2700 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpVersaCAD", "EndVersaCAD")
@Endif

@Goto MenuCADsys

/*------------- AutoCAD 10, 11 Driver Installation (2100)-----------------*/
MenuACAD:
@ClearOption (2105)
@ClearOption (2110)
@ClearOption (2120)
@ClearOption (2125)
@ClearOption (2130)
@ClearOption (2145)
@EnableF1(1)

@GetOption @Cls
 @NameACAD @msgDDI
 @msgPSAV
 @Option 2105 = "ADI 4.2 Features and Commands Help Menu (Reading Recommended)"
 @Option 2130 = "AutoCAD Release 11 (Protected Mode ADI 4.2)"
 @Option 2145 = "AutoCAD Release 12 (Protected Mode ADI 4.2)"
 @Option 2120 = "AutoDesk's 3D Studio version 1.0 & 2.0 (PADI 4.2)"
 @Option 2125 = "AutoDesk's AutoShade version 2.1 (PADI 4.2)"
 @Option 2110 = "AutoCAD Release 10 & 11 (Real Mode ADI 4.1)"
@EndOption

@If (@Esc)
 @Goto MenuCADsys
@ElseIf (@KeyF1)
 @Goto MenuACADHelp
@ElseIf (2105 [=@Option)
     @Goto MenuADI42
@Endif

InputDirACAD:
@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
 @Cls
 @NameACAD @msgDDI
 @msgDrive














/* The @NameACAD display driver may be placed in any
 directory on your computer (e.g., C:\\ACAD)*/
@EndOutDrive
@If (@Esc) @Goto MenuACAD @Endif

@GetSubdir
 @If (2110 [= @Option)
  @Default = "\\ACAD"
 @Elseif (2120 [= @Option)
  @Default = "\\3DS"
 @Elseif (2125 [= @Option)
  @Default = "\\SHADE"
 @Elseif (2130 [= @Option)
  @Default = "\\ACAD11"
 @Elseif (2145 [= @Option)
  @Default = "\\ACAD12"
 @Endif
 @Cls
 @NameACAD @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuACAD @Endif

@ClearOption(1)
@ClearOption(2)
@If ((@Exists "@OutDrive:\\@SubDir") == 0)
 @EnableF1(0)
 @GetOption
  @LocalWindow (10,39) 
  @Cls
  @NameACAD @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
 @EndOption
@Endif

@If (@Esc)
 @Goto MenuACAD
@ElseIf (1 [= @Option)
  @Goto InputDirACAD
@Endif

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 
 @F 15x25.fnt     @O @OutDrive:\@SubDir\*.* @Option 2120
 @F 16x30.fnt     @O @OutDrive:\@SubDir\*.* @Option 2120 
 @F 6x9.fnt       @O @OutDrive:\@SubDir\*.* @Option 2120 
 @F 8x16.fnt      @O @OutDrive:\@SubDir\*.* @Option 2120 
 @F 9x15.fnt      @O @OutDrive:\@SubDir\*.* @Option 2120
 @F 12x24.fnt     @O @OutDrive:\@SubDir\*.* @Option 2120
 @F 12x20.fnt     @O @OutDrive:\@SubDir\*.* @Option 2120
 @F rcfadi42.exp  @O @OutDrive:\@SubDir\*.* @Option 2120
 
 @F 15x25.fnt     @O @OutDrive:\@SubDir\*.* @Option 2125
 @F 16x30.fnt     @O @OutDrive:\@SubDir\*.* @Option 2125 
 @F 6x9.fnt       @O @OutDrive:\@SubDir\*.* @Option 2125 
 @F 8x16.fnt      @O @OutDrive:\@SubDir\*.* @Option 2125 
 @F 9x15.fnt      @O @OutDrive:\@SubDir\*.* @Option 2125
 @F 12x24.fnt     @O @OutDrive:\@SubDir\*.* @Option 2125
 @F 12x20.fnt     @O @OutDrive:\@SubDir\*.* @Option 2125
 @F rcfadi42.exp  @O @OutDrive:\@SubDir\*.* @Option 2125
 
 @F 15x25.fnt     @O @OutDrive:\@SubDir\*.* @Option 2130
 @F 16x30.fnt     @O @OutDrive:\@SubDir\*.* @Option 2130 
 @F 6x9.fnt       @O @OutDrive:\@SubDir\*.* @Option 2130 
 @F 8x16.fnt      @O @OutDrive:\@SubDir\*.* @Option 2130 
 @F 9x15.fnt      @O @OutDrive:\@SubDir\*.* @Option 2130
 @F 12x24.fnt     @O @OutDrive:\@SubDir\*.* @Option 2130
 @F 12x20.fnt     @O @OutDrive:\@SubDir\*.* @Option 2130
 @F rcfadi42.exp  @O @OutDrive:\@SubDir\*.* @Option 2130

 @F 15x25.fnt     @O @OutDrive:\@SubDir\DRV\*.* @Option 2145
 @F 16x30.fnt     @O @OutDrive:\@SubDir\DRV\*.* @Option 2145 
 @F 6x9.fnt       @O @OutDrive:\@SubDir\DRV\*.* @Option 2145 
 @F 8x16.fnt      @O @OutDrive:\@SubDir\DRV\*.* @Option 2145 
 @F 9x15.fnt      @O @OutDrive:\@SubDir\DRV\*.* @Option 2145
 @F 12x24.fnt     @O @OutDrive:\@SubDir\DRV\*.* @Option 2145
 @F 12x20.fnt     @O @OutDrive:\@SubDir\DRV\*.* @Option 2145
 @F rcfadi42.exp  @O @OutDrive:\@SubDir\DRV\*.* @Option 2145
 
 /* ACAD 10 Real Mode */
 @F fadi.exe    @O @OutDrive:\@SubDir\*.* @Option 2110


 @EndLib 
@EndDisk

@If (2110 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpACAD10r", "EndACAD10r")
@Elseif (2120 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "DSPADI",
	     "SET DSPADI=@OutDrive:\\@SubDir\\rcfadi42.exp", "REPLACE")
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "RDPADI",
	     "SET RDPADI=@OutDrive:\\@SubDir\\rcfadi42.exp", "REPLACE")
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "RCPADI",
	     "SET RCPADI=@OutDrive:\\@SubDir\\rcfadi42.exp", "REPLACE")
 @Goto SetAQUILA
EndFONTDS:
 @Help ("@ExePath\\install.hlp", "Help3DS", "End3DS")
@ElseIf (2125 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "DSPADI",
	     "SET DSPADI=@OutDrive:\\@SubDir\\rcfadi42.exp", "REPLACE")
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "RDPADI",
	     "SET RDPADI=@OutDrive:\\@SubDir\\rcfadi42.exp", "REPLACE")
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "RCPADI",
	     "SET RCPADI=@OutDrive:\\@SubDir\\rcfadi42.exp", "REPLACE")
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "SHADE",
	     "SET SHADE=@OutDrive:\\@SubDir\\rmansupt", "REPLACE")
 @Goto SetAQUILA
EndFONTS:
 @Help ("@ExePath\\install.hlp", "HelpShade", "EndShade")
@Elseif (2130 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "DSPADI",
	     "SET DSPADI=@OutDrive:\\@SubDir\\rcfadi42.exp", "REPLACE")
 @Goto SetAQUILA
EndFONTA:
 @Help ("@ExePath\\install.hlp", "HelpACAD11", "EndACAD11")
@Elseif (2145 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "DSPADI",
	     "SET ACADDRV=@OutDrive:\\@SubDir\\drv\\", "REPLACE")
 @Goto SetAQUILA
EndFONTC:
 @Help ("@ExePath\\install.hlp", "HelpACAD12", "EndACAD12") 

@EndIf   
			  
@Goto MenuACAD

/*----------------------- ADI 4.2 Help -----------------------------------*/

MenuADI42:
@ClearOption(2910)
@ClearOption(2920)
@ClearOption(2925) 
@ClearOption(2930)
@ClearOption(2933)  
@ClearOption(2935)  
@ClearOption(2940)
@ClearOption(2950)
@ClearOption(2953)  
@ClearOption(2955)  
@ClearOption(2960)
@ClearOption(2965)
@ClearOption(2970) 
 @EnableF1(0)
 @GetOption
 @Cls
	












  @Option 2910 = "List of Features, Fonts, and Resolutions"
  @Option 2920 = "Screen Layout and Graphics Flip Screen"
  @Option 2925 = "Display List Configuration"
  @Option 2930 = "Birds-Eye View" 
  @Option 2933 = "Birds-Eye Icons"
  @Option 2935 = "Edge Pan, Page Alarm"
  @Option 2940 = "Erase Buffer and Band-Free Rendering" 
  @Option 2950 = "Fahrenheit Driver Commands Part 1"
  @Option 2953 = "Fahrenheit Driver Commands Part 2"
  @Option 2955 = "Fahrenheit Quick Reference Driver Commands"
  @Option 2960 = "Custom Menu Design"
  @Option 2965 = "AutoCAD Performance Tuning"
  @Option 2970 = "Known Bug List and Upgrade Information"
 


  @EndOption


 @If (@Esc)
     @Goto MenuACAD
@ElseIf (2910 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpFeatures", "EndFeatures")
@ElseIf (2920 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpLayout", "EndLayout")
@ElseIf (2925 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpDLC", "EndDLC")
@ElseIf (2930 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpBird", "EndBird")
@ElseIf (2933 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpIcon", "EndIcon")
@ElseIf (2935 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpPan", "EndPan")
@ElseIf (2940 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpBand", "EndBand")
@ElseIf (2950 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpCommands", "EndCommands")
@ElseIf (2953 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpComtwo", "EndComtwo")
@ElseIf (2955 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpComquick", "EndComquick")
@ElseIf (2960 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpCMD", "EndCMD")
@ElseIf (2965 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpTuning", "EndTuning")
@ElseIf (2970 [=@Option)
     @Help ("@ExePath\\install.hlp", "HelpBug", "EndBug")

@endif
@Goto MenuADI42



/*---------------------- Handle AutoCAD Help Menu -------------------------*/
MenuACADHelp:

@If (2110 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpACAD10r", "EndACAD10r")
@Elseif (2105 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpADI42", "EndADI42")
@ElseIf (2120 [= @Option)
 @Help ("@ExePath\\install.hlp", "Help3DS", "End3DS")
@Elseif (2125 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpShade", "EndShade")
@Elseif (2130 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpACAD11", "EndACAD11")
@Elseif (2145 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpACAD12", "EndACAD12")
@EndIf   

@Goto MenuACAD

/*------------------ CADKey Driver Installation (2200) -------------------*/
MenuCADKey:

@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
 @Cls
 @NameCADKey @msgDDI
 @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuCADsys @Endif

@GetSubdir
 @Default = "\\CADKEY"
 @Cls
 @NameCADKey @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuCADKey @Endif

/* Check dir */
@ClearOption(1)
@ClearOption(2)
@EnableF1(0)
@GetOption
 @LocalWindow (10,39) 
 @If (@Exists "@OutDrive:\\@SubDir" == 0)
  @Cls
  @NameCADKey @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
 @ElseIf (@Exists "@OutDrive:\\@SubDir\\grdev.dat" == 0)
  @Cls
  @NameCADKey @msgDDI
  The grdev.dat file is not found in your input directory:
  @OutDrive:@SubDir
  @NameCADKey @msgNPI
 @Else
  @Goto CopyFileCADKey
 @EndIf
 @Option 1 = "@Reenter"
 @Option 2 = "@Cont"
@EndOption
@If ((@Esc) || (1 [= @Option))
  @Goto MenuCADKey
@Endif

CopyFileCADKey:
@Rename ("@OutDrive:\\@Subdir\\grdev.dat","grdev.000")
@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 @F ck_911.exe  @O @OutDrive:\@SubDir\*.*
 @F grdev.dat   @O @OutDrive:\@SubDir\*.orc 
 @EndLib 
@EndDisk

@Delete ("@OutDrive:\\@Subdir\\grdev.dat")
@CatFiles ("@OutDrive:\\@Subdir\\grdev.dat","@OutDrive:\\@Subdir\\grdev.000")
@CatFiles ("@OutDrive:\\@Subdir\\grdev.dat","@OutDrive:\\@Subdir\\grdev.orc")
@Delete ("@OutDrive:\\@Subdir\\grdev.orc")
				  
@Help ("@ExePath\\install.hlp", "HelpCADKey", "EndCADKey")
@Goto MenuCADsys

/*----------------- DataCAD Driver Installation (2300) -------------------*/
MenuDataCAD:

@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
 @Cls
 @NameDataCAD @msgDDI
 @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuCADsys @Endif

@GetSubdir
 @Default = "\\MTEC\\DRV"
 @Cls
 @NameDataCAD @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuDataCAD @Endif

/* Check dir */
@ClearOption(1)
@ClearOption(2)
@EnableF1(0)
@GetOption
 @LocalWindow (10,39) 
 @If (@Exists "@OutDrive:\\@SubDir" == 0)
  @Cls
  @NameDataCAD @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
 @ElseIf ((@Exists "@OutDrive:\\@SubDir\\drivers.gd2" == 0) ||
	  (@Exists "@OutDrive:\\@SubDir\\drivers.gd4" == 0))
  @Cls
  @NameDataCAD @msgDDI
  The drivers.gd2/drivers.gd4 file is not found in your input directory:
  @OutDrive:@SubDir
  DataCAD @msgNPI
 @Else
  @Goto CopyFileDataCAD
 @EndIf
 @Option 1 = "@Reenter"
 @Option 2 = "@Cont"
@EndOption
@If ((@Esc) || (1 [= @Option))
  @Goto MenuDataCAD
@Endif

CopyFileDataCAD:
@Rename ("@OutDrive:\\@Subdir\\drivers.gd2","drivers.oc2")
@Rename ("@OutDrive:\\@Subdir\\drivers.gd4","drivers.oc4")
@Delete ("@OutDrive:\\@Subdir\\drivers.gd2")
@Delete ("@OutDrive:\\@Subdir\\drivers.gd4")

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 @F ck_911.exe   @O @OutDrive:\@SubDir\*.*
 @F dl_911.exe   @O @OutDrive:\@SubDir\*.*
 @F drivers.gd2  @O @OutDrive:\@SubDir\orchid.*
 @F drivers.gd4  @O @OutDrive:\@SubDir\orchid.*
 @EndLib 
@EndDisk

@CatFiles ("@OutDrive:\\@Subdir\\drivers.gd2","@OutDrive:\\@Subdir\\drivers.oc2")
@CatFiles ("@OutDrive:\\@Subdir\\drivers.gd2","@OutDrive:\\@Subdir\\orchid.gd2")
@CatFiles ("@OutDrive:\\@Subdir\\drivers.gd4","@OutDrive:\\@Subdir\\drivers.oc4")
@CatFiles ("@OutDrive:\\@Subdir\\drivers.gd4","@OutDrive:\\@Subdir\\orchid.gd4")
@Delete ("@OutDrive:\\@Subdir\\orchid.gd2")
@Delete ("@OutDrive:\\@Subdir\\orchid.gd4")

@Help ("@ExePath\\install.hlp", "HelpDataCAD", "EndDataCAD")
@Goto MenuCADsys

/*--------------- CADVance Driver Installation (2400) --------------------*/
MenuCADVance:

@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
 @Cls
 @NameCADVance @msgDDI
 @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuCADsys @Endif

@GetSubdir
 @Default = "\\CADVANCE"
 @Cls
 @NameCADVance @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuCADVance @Endif

/* Check dir */
@ClearOption(1)
@ClearOption(2)
@If ((@Exists "@OutDrive:\\@SubDir") == 0)
  @EnableF1(0)
  @GetOption
  @LocalWindow (10,39)
  @Cls
  @NameCADVance @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
  @EndOption
@Endif

@If ((@Esc) || (1 [= @Option))
  @Goto MenuCADVance
@Endif

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 @F cdv911.drv      @O @OutDrive:\@SubDir\*.*
 @EndLib 
@EndDisk

/* Set s31_911=x in autoexec.bat, x = {0,1,2,3,4,5,7} */
@Goto SetS3911

EndCADVance:
@Help ("@ExePath\\install.hlp", "HelpCADVance", "EndCADVance")
@Goto MenuCADsys

/*-------------- Generic CADD Driver Installation (2500) -----------------*/
MenuGenCADD:

@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
  @Cls
  @NameGenCADD @msgDDI
  @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuCADsys @Endif

@GetSubdir
 @Default = "\\GENERIC"
 @Cls
 @NameGenCADD @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuGenCADD @Endif

@ClearOption(1)
@ClearOption(2)
@If (@Exists "@OutDrive:\\@SubDir" == 0)
 @EnableF1(0)
 @GetOption @Cls
  @LocalWindow (10,39) 
  @NameGenCADD @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont

  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
 @EndOption
@Endif

@If ((@Esc) || (1 [= @Option))
 @Goto MenuGenCADD
@Endif

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 @F f1280l.vgd  @O @OutDrive:\@SubDir\*.*
 @EndLib 
@EndDisk

/* Set s31_911=x in autoexec.bat, x = {0,1,2,3,4,5,7} */
@Goto SetS3911

EndGenCADD:
@Help ("@ExePath\\install.hlp", "HelpGenCADD", "EndGenCADD")
@Goto MenuCADsys

/*--- MicroStation Driver (real and protected mode) Instllation (2600) ---*/
MenuMicroCAD:

@ClearOption (2610) 
@ClearOption (2620)
@EnableF1(1)
@GetOption @Cls
 @NameMicroCAD @msgDDI
 @msgPSAV
 @Option 2610 = "MicroStation (Real Mode)"
 @Option 2620 = "MicroStation (Protected Mode)"
@EndOption

@If (@Esc)
 @Goto MenuCADsys
@ElseIf (@KeyF1)
 @Goto MenuMicroCADHelp
@Endif

InputDirMicroCAD:
@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
 @Cls
 @NameMicroCAD @msgDDI
 @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuMicroCAD @Endif

@GetSubdir
 @Default = "\\USTATION\\DRIVERS"
 @Cls
 @NameMicroCAD @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto InputDirMicroCAD @Endif

@ClearOption(1)
@ClearOption(2)
@If (@Exists "@OutDrive:\\@SubDir" == 0)
 @EnableF1(0)
 @GetOption
  @LocalWindow (10,39)
  @Cls
  @NameMicroCAD @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
 @EndOption
@Endif

@If ((@Esc) || (1 [= @Option))
 @Goto InputDirMicroCAD
@Endif

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
  @F mgls3.exe   @O @OutDrive:\@SubDir\*.* @Option 2610
  @F mgls3.mgl   @O @OutDrive:\@SubDir\*.* @Option 2610
  @F remove.exe  @O @OutDrive:\@SubDir\*.* @Option 2610

  @F mgl911.exp  @O @OutDrive:\@SubDir\*.* @Option 2620
  @F mgl911.ma   @O @OutDrive:\@SubDir\*.* @Option 2620
  @F mgl911.mgl  @O @OutDrive:\@SubDir\*.* @Option 2620 
 @EndLib 
@EndDisk

/* Set s31_911=x in autoexec.bat, x = {0,1,2,3,4,5,7} */
@Goto SetS3911

EndMicroCAD:

@If (2610 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpMicroCADr", "EndMicroCADr")
@ElseIf (2620 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpMicroCADp", "EndMicroCADp")
@EndIf   

@Goto MenuCADsys

/*------------------ Handle MicroStation Help Menu -----------------------*/
MenuMicroCADHelp:

@If (2610 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpMicroCADr", "EndMicroCADr")
@ElseIf (2620 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpMicroCADp", "EndMicroCADp")
@EndIf   

@Goto MenuMicroCAD


/*-------------- VersaCAD Driver Installation (2700) ---------------------*/
MenuVersaCAD:

@EnableF1(1)
@ClearOption (2710)
@ClearOption (2750)
@GetOption @Cls
 @NameVersaCAD @msgDDI
 @msgPSAV
 @Option 2750 = "VersaCAD 386 (Protected Mode)"
 @Option 2710 = "VersaCAD Designer (Real Mode)"
@EndOption

@If (@Esc)
 @Goto MenuCADsys
@Elseif (@KeyF1)
 @Help ("@ExePath\\install.hlp", "HelpVersaCAD", "EndVersaCAD")
 @Goto MenuVersaCAD
@Endif

InputDirVersaCAD:
@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
 @Cls
 @NameVersaCAD @msgDDI
 @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuVersaCAD @Endif

@GetSubdir
 @Default = "\\VCAD"
 @Cls
 @NameVersaCAD @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto InputDirVersaCAD @Endif

@ClearOption(1)
@ClearOption(2)
@If ((@Exists "@OutDrive:\\@SubDir") == 0)
 @EnableF1(0)
 @GetOption
 @LocalWindow (10,39)
 @Cls
  @NameVersaCAD @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
 @EndOption
@Endif
@If ((@Esc) || (1 [= @Option))
 @Goto InputDirVersaCAD
@Endif

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 @F remove.exe  @O @OutDrive:\@SubDir\*.*
 @F vc2_911.com @O @OutDrive:\@SubDir\*.* @Option 2710
 @F vcadreal.cfg  @O @OutDrive:\@SubDir\*.* @Option 2710
 @F vc3_911.com @O @OutDrive:\@SubDir\*.* @Option 2750
 @F vcad386.cfg @O @OutDrive:\@SubDir\*.* @Option 2750
 @F vcad386.bat @O @OutDrive:\*.* @Option 2750
 @EndLib 
@EndDisk
				  
@Help ("@ExePath\\install.hlp", "HelpVersaCAD", "EndVersaCAD")
@Goto MenuCADsys

/*---------------- Desktop Publishing Menu (3000) ------------------------*/
MenuDesktop:

@ClearOption(3100)
@ClearOption(3200)
@EnableF1(1)
@GetOption
@Cls
 @NameDesk @msgDDI
 @msgPSAA
 @Option 3100 = "@NameVentura"
 @Option 3200 = "@NameGem"
@EndOption

@If (@Esc)
 @Goto MenuMain
@Elseif (@KeyF1)
 @Goto MenuDesktopHelp 
@Elseif (3100 [= @Option)
 @Goto MenuVentura
@Else
 @Goto MenuGem
@Endif

/*-------------------- Handles Desktop Publishing Help Menu --------------*/
MenuDesktopHelp:

@If (3100 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpVentura", "EndVentura")
@Elseif (3200 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpGem", "EndGem")
@Endif

@Goto MenuDesktop

/*-------------- Ventura Publisher Driver Installation (3100) ------------*/
MenuVentura:

@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
  @Cls
  @NameVentura @msgDDI
  @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuDesktop @Endif

@GetSubdir
 @Default = "\\VENTURA"
 @Cls
 @NameVentura @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuVentura @Endif

@ClearOption(1)
@ClearOption(2)
@If (@Exists "@OutDrive:\\@SubDir" == 0)
 @EnableF1(0)
 @GetOption @Cls
  @LocalWindow (10,39) 
  @NameVentura @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
 @EndOption
@Endif

@If ((@Esc) || (1 [= @Option))
 @Goto MenuVentura
@Endif

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 @F sdgemvp.vga @O @OutDrive:\@SubDir\*.*
 @F sysfont.bg  @O @OutDrive:\@SubDir\*.*
 @EndLib 
@EndDisk

/* Undone:
   Modify vp.bat/vpprof.bat
*/

/* Set S31_911=x in autoexec.bat, x = {0,1,2,3,4} */
@Goto SetS3911

EndVentura:                               
@Help ("@ExePath\\install.hlp", "HelpVentura", "EndVentura")
@Goto MenuDesktop

/*-------------- Gem Desktop Driver Installation (3200) ------------------*/
MenuGem:

@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
  @Cls
  @NameGem @msgDDI
  @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuDesktop @Endif

@GetSubdir
 @Default = "\\GEMAPPS\\GEMSYS"
 @Cls
 @NameGem @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuGem @Endif

/* Check dir */
@ClearOption(1)
@ClearOption(2)
@If ((@Exists "@OutDrive:\\@SubDir") == 0)
 @EnableF1(0)
 @GetOption @Cls
  @LocalWindow (10,39) 
  @NameGem @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
 @EndOption
@Endif

@If ((@Esc) || (1 [= @Option))
 @Goto MenuGem
@Endif

@Rename ("@OutDrive:\\@SubDir\\sd*.vga","sd*.bak")
@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 @F sdgemvp.vga @O @OutDrive:\@SubDir\*.*
 @F sysfont.bg  @O @OutDrive:\@SubDir\*.*
 @EndLib 
@EndDisk

/* Set S31_911=x in autoexec.bat, x = {0,1,2,3,4} */
@Goto SetS3911

EndGem:
@Help ("@ExePath\\install.hlp", "HelpGem", "EndGem")
@Goto MenuDesktop

/*--------------- Word Processing Main Menu (5000) -----------------------*/
MenuWordProcess:

@ClearOption(5100)
@ClearOption(5200)
@EnableF1(1)
@GetOption
@Cls
 @NameWord @msgDDI
 @msgPSAA
 @Option 5100 = "@NameWP"
 @Option 5200 = "@NameMSWord"
@EndOption

@If (@Esc)
 @Goto MenuMain
@Elseif (@KeyF1)
 @Goto MenuWordHelp
@Elseif (5100 [= @Option)
 @Goto MenuWP
@Elseif (5200 [= @Option)
 @Goto MenuMSWord
@Endif

/*-------------------- Handles Word Processing Menu Help ------------------*/
MenuWordHelp:

@If (5100 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpWP", "EndWP")
@Elseif (5200 [= @Option)
 @Help ("@ExePath\\install.hlp", "HelpMSWord", "EndMSWord")
@Endif

@Goto MenuWordProcess

/*----------------- WordPerfect Driver Installation (5100) ---------------*/
MenuWP:

@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
  @Cls
  @NameWP @msgDDI
  @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuWordProcess @Endif

@GetSubdir
 @Default = "\\WP"
 @Cls
 @NameWP @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuWP @Endif

@ClearOption(1)
@ClearOption(2)
@If ((@Exists "@OutDrive:\\@SubDir") == 0)
 @EnableF1(0)
 @GetOption @Cls
  @LocalWindow (10,39) 
  @NameWP @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
 @EndOption
@Endif

@If ((@Esc) || (1 [= @Option))
 @Goto MenuWP
@Endif

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 @F wpgraph.vrs @O @OutDrive:\@SubDir\*.* 
 @F wptext.vrs @O @OutDrive:\@SubDir\*.* 
 @EndLib 
@EndDisk

@Help ("@ExePath\\install.hlp", "HelpWP", "EndWP")
@Goto MenuWordProcess

/*------------ Microsoft Word Driver Installation (5200) -----------------*/
MenuMSWord:

@EnableF1(0)
@GetOutDrive
 @Suppress A
 @Suppress B
  @Cls
  @NameMSWord @msgDDI
  @msgDrive
@EndOutDrive
@If (@Esc) @Goto MenuWordProcess @Endif

@GetSubdir
 @Default = "\\WORD"
 @Cls
 @NameMSWord @msgDDI
 @msgDir


@EndSubdir
@If (@Esc) @Goto MenuMSWord @Endif

@ClearOption(1)
@ClearOption(2)
@If ((@Exists "@OutDrive:\\@SubDir") == 0)
 @EnableF1(0)
 @GetOption @Cls
  @LocalWindow (10,39) 
  @NameMSWord @msgDDI
  @OutDrive:@SubDir @msgDDNE
  @msgCont
  @Option 1 = "@Reenter"
  @Option 2 = "@Cont"
 @EndOption
@Endif

@If ((@Esc) || (1 [= @Option))
 @Goto MenuMSWord
@Endif

@DefineDisk
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
 @F screen.vid @O @OutDrive:\@SubDir\*.* 
 @EndLib 
@EndDisk

@Help ("@ExePath\\install.hlp", "HelpMSWord", "EndMSWord")
@Goto MenuWordProcess

/*---------- This block sets the S31_911 variable in autoexec.bat ---------*/
SetS3911:

@ClearOption (0)
@ClearOption (1)
@ClearOption (2)
@ClearOption (3)
@ClearOption (4)
@ClearOption (5)
@ClearOption (7)
@EnableF1(0)
@GetOption
 @If (2400 [= @Option)
  @Cls
  @NameCADVance @msgDDI
  Please Select a Resolution:
 @Elseif (2500 [= @Option)
  @Cls
  @NameGenCADD @msgDDI
  Please Select a Resolution:
 @Elseif (2600 [= @Option)
  @Cls
  @NameMicroCAD @msgDDI
  Please Select a Resolution:
 @Elseif (3100 [= @Option)
  @Cls
  @NameVentura @msgDDI
  Please Select a Resolution:
 @Elseif (3200 [= @Option)
  @Cls
  @NameGem @msgDDI
  Please Select a Resolution:
 @Endif
   @Option 4 = "1024 x 768,  256 colors"
   @Option 2 = "800  x 600,  256 colors"
   @Option 0 = "640  x 480,  256 colors"     
   @Option 7 = "1280 x 1024, 16  colors"
   @Option 5 = "1280 x 960,  16  colors"
   @Option 3 = "1024 x 768,  16  colors"
   @Option 1 = "800  x 600,  16  colors"
@EndOption

@If (@Esc)
 @Goto EndS3911
@Elseif (0 [= @Option)
 @Value(0)
@Elseif (1 [= @Option)
 @Value(1)
@Elseif (2 [= @Option)
 @Value(2)
@Elseif (3 [= @Option)
 @Value(3)
@Elseif (4 [= @Option)
 @Value(4)
@Elseif (5 [= @Option)
 @Value(5)
@Else
 @Value(7)
@Endif

@WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "S31_911",
	    "SET S31_911=@Value()", "REPLACE")

EndS3911:

@If (2400 [= @Option)
 @Goto EndCADVance
@Elseif (2500 [= @Option)
 @Goto EndGenCADD
@Elseif (2600 [= @Option)
 @Goto EndMicroCAD
@Elseif (3100 [= @Option)
 @Goto EndVentura
@Elseif (3200 [= @Option)
 @Goto EndGem
@Else
 @Goto MenuCADsys
#Endif

/*----- This block sets the AQUILA_FONT statement in autoexec.bat --*/

SetAQUILA:
MenuRETURN:
@ClearOption(50)  /*YES*/
@ClearOption(51)  /*NO*/
@EnableF1(1)

@GetOption
 @LocalWindow (10,40)
 @Cls
 Do you wish to select a different Font Size other than 8x16 (Default)?
 (Hit the <F1> Key for more information on Font Sizes.)
 @Option 50 = "YES"
 @option 51 = "NO"
@EndOption

@If (@Esc)
 @Goto MenuRETURN
@Elseif (@KeyF1)
     @Help ("@ExePath\\install.hlp","HelpFONT","EndFONT")
@Elseif (50 [= @Option)
 @Goto MenuFNT
@Elseif (51 [= @Option)
 @Goto EndAquila
@Endif
@Goto MenuRETURN 




MenuFNT:
@ClearOption (10)
@ClearOption (11)
@ClearOption (12)
@ClearOption (13)
@ClearOption (14)
@ClearOption (15)
@ClearOption (16)
@EnableF1(0)
@GetOption
 @If (2125 [= @Option)
  @Cls
  AutoShade @msgDDI
  Please Select a Font Size:
 @Elseif (2120 [= @Option)
  @Cls
  3D Studio @msgDDI
  Please Select a Font Size:
 @Elseif (2130 [= @Option)
  @Cls
  AutoCAD 11 @msgDDI
  Please Select a Font Size:
 @Elseif (2145 [= @Option)
  @Cls
  AutoCAD 12 @msgDDI
  Please Select a Font Size:
 @Endif
   @Option 10 = "6x9"
   @Option 11 = "9x15"
   @Option 12 = "8x16"
   @Option 13 = "12x20"     
   @Option 14 = "12x24"
   @Option 15 = "15x25"
   @Option 16 = "16x30"
@EndOption

@If (@Esc)
 @Goto EndAquila
@Elseif (10 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "SET AQUILA_FONT",
	     "SET AQUILA_FONT=6x9.fnt", "REPLACE")
@Elseif (11 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "SET AQUILA_FONT",
	     "SET AQUILA_FONT=9x15.fnt", "REPLACE")
@Elseif (12 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "SET AQUILA_FONT",
	     "SET AQUILA_FONT=8x16.fnt", "REPLACE")
@Elseif (13 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "SET AQUILA_FONT",
	     "SET AQUILA_FONT=12x20.fnt", "REPLACE")
@Elseif (14 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "SET AQUILA_FONT",
	     "SET AQUILA_FONT=12x24.fnt", "REPLACE")
@Elseif (15 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "SET AQUILA_FONT",
	     "SET AQUILA_FONT=15x25.fnt", "REPLACE")
@Elseif (16 [= @Option)
 @WriteFile ("@BootDrive:\\autoexec.bat", "NOSECTION", "SET AQUILA_FONT",
	     "SET AQUILA_FONT=16x30.fnt", "REPLACE")
@Endif

EndAquila:

@If (2125 [= @Option)
 @Goto EndFONTS
@Elseif (2120 [= @Option)
 @Goto EndFONTDS
@Elseif (2130 [= @Option)
 @Goto EndFONTA
@Elseif (2145 [= @Option)
 @Goto EndFONTC
@Else
 @Goto MenuCADsys
@Endif


/*-------------------- Sample disk build utility ------------------*/

MenuSample:
@ClearOption(9010)
@ClearOption(9020)
@ClearOption(9030)
@ClearOption(9040) 
 @EnableF1(1)
 @GetOption
 @Cls
 @LocalWindow (10,39)   
  @Option 9010 = "Copy files from Master Drive A: to a Formatted Floppy Drive A:"
  @Option 9020 = "Copy files from Master Drive A: to a Formatted Floppy Drive B:"
  @Option 9030 = "Copy files from Master Drive B: to a Formatted Floppy Drive A:"
  @Option 9040 = "Copy files from Master Drive B: to a Formatted Floppy Drive B:"

 @EndOption


 @If (@Esc)
     @Goto MenuMain
  @Elseif (@KeyF1)
     @Help ("@ExePath\\install.hlp", "HelpCopy", "EndCopy")
  @ElseIf (9010 [=@Option)
     @Goto MenuAA
  @ElseIf (9020 [=@Option)
     @Goto MenuBB
  @ElseIf (9030 [=@Option)
     @Goto MenuAA
  @ElseIf (9040 [=@Option)
     @Goto MenuBB
@endif
@Goto MenuSample



/*--------------------- Information on AA   -----------------------*/
MenuAA:
@EnableF1(0)
@If (!@DriveExists(C))
    @Display
       This program requires a Hard Disk Drive to complete this copy.

      @Pause
    @Goto MenuMain
    @EndDisplay
@EndIf
@DefineDisk 
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
  @F ovnplay.exe   @O C:\Fahrenva\temp\*.*  
  @F speaker.drv   @O C:\Fahrenva\temp\*.*  
  @F disk.id       @O C:\Fahrenva\temp\*.*  
  @F installc.dat  @O C:\Fahrenva\temp\install.dat  
  @F installc.hlp  @O C:\Fahrenva\temp\install.hlp  
  @F copya.bat     @O C:\Fahrenva\temp\MAKEDISK.BAT  
 
 @EndLib
 @F Finstall.exe   @O C:\Fahrenva\temp\install.exe 
@EndDisk

@Display                    
 @Cls
  @System "C:\\Fahrenva\\temp\\makedisk.bat"
 @Cls
 @Help ("@ExePath\\install.hlp", "HelpCopy", "EndCopy")
 @Cls






 Voice Notes Playback Diskette Copy Now Completed....
	
	To repeat, just type "MAKEDISK" from the \FAHRENVA\TEMP Subdirectory.

	       Press any key to return to the Main Menu.





  @Pause
@EndDisplay

@Goto MenuMain



/*--------------------- Information on BB   -----------------------*/
MenuBB:
@EnableF1(0)
@If (!@DriveExists(C))
    @Display
       This program requires a Hard Disk Drive to complete this copy.

      @Pause
    @Goto MenuMain
    @EndDisplay
@EndIf

@DefineDisk 
 @Label = "Disk #1"
 @BeginLib FAHDRVVA.001 
  @F ovnplay.exe   @O C:\Fahrenva\temp\*.*  
  @F speaker.drv   @O C:\Fahrenva\temp\*.*  
  @F disk.id       @O C:\Fahrenva\temp\*.*  
  @F installc.dat  @O C:\Fahrenva\temp\install.dat  
  @F installc.hlp  @O C:\Fahrenva\temp\install.hlp  
  @F copyb.bat     @O C:\Fahrenva\temp\MAKEDISK.BAT  
 
 @EndLib
 @F finstall.exe   @O C:\fahrenva\temp\install.exe 
@EndDisk

@Display                    
 @Cls
  @System "C:\\fahrenva\\temp\\makedisk.bat"
 @Cls
 @Help ("@ExePath\\install.hlp", "HelpCopy", "EndCopy")
 @Cls






 Voice Notes Playback Diskette Copy Now Completed....
	
	To repeat, just type "MAKEDISK" from the \FAHRENVA\TEMP Subdirectory.

	       Press any key to return to the Main Menu.





  @Pause
@EndDisplay

@Goto MenuMain
---------------------------------------------------

